opensearch-neural-search-plugin/trunk/PKGBUILD

   1 # Maintainer: Justin Kromlinger <hashworks@archlinux.org>
   2
   3 pkgname=opensearch-neural-search-plugin
   4 pkgver=2.6.0.0
   5 pkgrel=1
   6 _opensearchver=2.6.0
   7 _jdkver=11
   8 pkgdesc="OpenSearch Neural Search Plugin"
   9 arch=('x86_64')
  10 # No docs website available yet
  11 url="https://github.com/opensearch-project/neural-search"
  12 license=('Apache')
  13 depends=("opensearch=${_opensearchver}")
  14 makedepends=("java-environment=${_jdkver}" 'unzip')
  15 source=(
  16   "${pkgname}-${pkgver}.tar.gz::https://github.com/opensearch-project/neural-search/archive/${pkgver}.tar.gz"
  17 )
  18 sha256sums=('d2a827e798a414a576227e3bb64341e42ec00c35e99000651cca19023f2b9c84')
  19
  20 build() {
  21   cd "neural-search-${pkgver}"
  22   export JAVA_HOME="/usr/lib/jvm/java-${_jdkver}-openjdk"
  23   export PATH="/usr/lib/jvm/java-${_jdkver}-openjdk/bin:$PATH"
  24   export GRADLE_OPTS="-Dbuild.snapshot=false -Dopensearch.version=${_opensearchver}"
  25   # integTest (Reaper) requires JDK 14
  26   ./gradlew build \
  27     --exclude-task "integTest" \
  28     --exclude-task "jacocoTestReport" \
  29     --exclude-task "jacocoTestCoverageVerification"
  30 }
  31
  32 package() {
  33   install -dm755 "${pkgdir}/usr/share/opensearch/plugins/opensearch-neural-search"
  34   cd "${pkgdir}/usr/share/opensearch/plugins/opensearch-neural-search"
  35   unzip "${srcdir}/neural-search-${pkgver}/build/distributions/opensearch-neural-search-${pkgver}.zip"
  36
  37   install -Dm644 "${srcdir}/neural-search-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  38 }