pam-u2f/trunk/PKGBUILD

   1 # Maintainer: Maxim Baz <archlinux at maximbaz dot com>
   2 # Contributor: Maxime de Roucy <maxime.deroucy@gmail.com>
   3 # Contributor: David Manouchehri <manouchehri@riseup.net>
   4 # Contributor: Sven Lechner <SirWindfield@users.noreply.github.com>
   5
   6 pkgname=pam-u2f
   7 _name="${pkgname/-/_}"
   8 pkgver=1.3.0
   9 pkgrel=1
  10 pkgdesc='Universal 2nd Factor (U2F) PAM authentication module from Yubico'
  11 arch=('x86_64')
  12 url='https://developers.yubico.com/pam-u2f'
  13 license=('BSD')
  14 replaces=("${_name}")
  15 depends=('libfido2' 'openssl' 'pam')
  16 makedepends=('asciidoc')
  17 source=("${url}/Releases/${_name}-${pkgver}.tar.gz"{,.sig})
  18 b2sums=('602ce0fd00105f7fbdea1805a5efde1302149d9f7977f3c52d576d7f4b9a1a95678b1463f19107b494e62c3722e319e05e0ec54f5839f70b855b59eecdf92112'
  19         'SKIP')
  20 validpgpkeys=(
  21     'B70D62AA6A31AD6B9E4F9F4BDC8888925D25CA7A' # Alessio Di Mauro <alessio@yubico.com>
  22     '78D997D53E9C0A2A205392ED14A19784723C9988' # Ludvig Michaelsson <ludvig.michaelsson@yubico.com>
  23 )
  24
  25 build() {
  26     cd "${_name}-${pkgver}"
  27     ./configure \
  28         --prefix=/usr \
  29         --with-pam-dir=/usr/lib/security
  30     make
  31 }
  32
  33 check() {
  34     cd "${_name}-${pkgver}"
  35     make check
  36 }
  37
  38 package() {
  39     cd "${_name}-${pkgver}"
  40     make DESTDIR="${pkgdir}" install
  41     install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" COPYING
  42 }
  43
  44 # vim:set ts=4 sw=4 et: