passenger/trunk/PKGBUILD

   1 # Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
   2
   3 pkgbase=passenger
   4 pkgname=(passenger mod_passenger nginx-mod-passenger)
   5 pkgver=6.0.17
   6 pkgrel=2
   7 pkgdesc="Fast and robust web server and application server for Ruby, Python and Node.js"
   8 arch=('x86_64')
   9 url="https://www.phusionpassenger.com"
  10 _watch="https://github.com/phusion/passenger/releases"
  11 license=('MIT')
  12 makedepends=('ruby-rake' 'ruby-rack' 'curl' 'apache' 'nginx-src')
  13 options=('!emptydirs' 'staticlibs')
  14 validpgpkeys=('D5F0851426939232F437AB722AC745A50A212A8C'
  15               '16378A33A6EF16762922526E561F9B9CAC40B2F7'  # auto-software-signing@phusion.nl
  16               'B0F4253373F8F6F510D42178520A9993A1C052F8') # Maxim Dounin <mdounin@mdounin.ru>
  17 source=(https://s3.amazonaws.com/phusion-passenger/releases/passenger-$pkgver.tar.gz{,.asc})
  18 sha256sums=('385559ed1d78eb83165222d568721dcc4222bb57c1939811ecd2c4ef33937ba7'
  19             'SKIP')
  20
  21 prepare() {
  22   mkdir -p build
  23   cd build
  24   ln -sf /usr/src/nginx/auto
  25   ln -sf /usr/src/nginx/src
  26 }
  27
  28 build() {
  29   cd build
  30   /usr/src/nginx/configure --with-compat --add-dynamic-module=../$pkgbase-$pkgver/src/nginx_module
  31   make modules
  32
  33   CFLAGS+=" -ffat-lto-objects"
  34   cd "$srcdir"/$pkgbase-$pkgver
  35   rake nginx CACHING=false
  36   ./bin/passenger-install-apache2-module -a
  37 }
  38
  39 package_passenger() {
  40   cd "$srcdir"/passenger-$pkgver
  41   depends=('ruby' 'ruby-rack' 'curl' 'libnsl')
  42
  43   mkdir -p "$pkgdir"/usr/lib/passenger/
  44   cp -R * "$pkgdir"/usr/lib/passenger/
  45
  46   install -Dm644 "$srcdir"/$pkgbase-$pkgver/LICENSE \
  47                  "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  48 }
  49
  50 package_mod_passenger() {
  51   pkgdesc="Passenger apache module"
  52   depends=('passenger' 'apache')
  53   install=passenger.install
  54
  55   cd "$srcdir"/passenger-$pkgver
  56
  57   mkdir -p "$pkgdir"/usr/lib/httpd/modules
  58   ln -sf /usr/lib/passenger/buildout/apache2/mod_passenger.so "$pkgdir"/usr/lib/httpd/modules/mod_passenger.so
  59
  60   install -Dm644 "$srcdir"/$pkgbase-$pkgver/LICENSE \
  61                  "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  62 }
  63
  64 package_nginx-mod-passenger() {
  65   pkgdesc="Passenger nginx module"
  66   depends=('passenger' "nginx")
  67
  68   install -Dm644 "$srcdir"/$pkgbase-$pkgver/LICENSE \
  69                  "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  70
  71   cd build/objs
  72   for mod in ngx_*.so; do
  73     install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
  74   done
  75
  76   install -Dm644 "$srcdir"/$pkgbase-$pkgver/LICENSE \
  77                  "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  78 }