pcsc-tools/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Alad Wenter <alad@archlinux.org>
   2 # Maintainer: Christian Hesse <mail@eworm.de>
   3 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   4 # Contributor: Lorenzo Nizzi Grifi Gargiolli <lorenzo.nizzi.grifi@gmail.com>
   5 # Contributor: marc0s <marc0s@fsfe.org>
   6
   7 pkgname=pcsc-tools
   8 pkgver=1.6.2
   9 pkgrel=1
  10 pkgdesc='PC/SC Architecture smartcard tools'
  11 arch=('x86_64')
  12 url='https://pcsc-tools.apdu.fr/'
  13 license=('GPL')
  14 depends=('pcsclite' 'pcsc-perl' 'glib-perl')
  15 makedepends=('pkg-config')
  16 optdepends=('perl-gtk3: gscriptor')
  17 validpgpkeys=('F5E11B9FFE911146F41D953D78A1B4DFE8F9C57E') # Ludovic Rousseau <rousseau@debian.org>
  18 source=("https://pcsc-tools.apdu.fr/${pkgname}-${pkgver}.tar.bz2"{,.asc})
  19 sha512sums=('20104baefa7928a86d21cee49d045cc35b8e74fec5be79ba5608ae046a110096efae96768d281e0f1350f71a889f89c675336d8264c75f8423369a49c03b42a8'
  20             'SKIP')
  21
  22 build() {
  23   cd "${srcdir}/${pkgname}-${pkgver}"
  24
  25   ./configure \
  26     --prefix=/usr
  27
  28   make
  29 }
  30
  31 package() {
  32   cd "${srcdir}/${pkgname}-${pkgver}"
  33
  34   make DESTDIR="${pkgdir}" install
  35 }