perl-cairo-gobject/trunk/PKGBUILD

   1 # Maintainer: Muflone http://www.muflone.com/contacts/english/
   2 # Contributor: 3ED <krzysztof1987 at gmail dot com>
   3
   4 pkgname=perl-cairo-gobject
   5 _perl_namespace=Cairo
   6 _perl_module=GObject
   7 pkgver=1.005
   8 pkgrel=1
   9 pkgdesc="Integrate Cairo into the Glib type system"
  10 arch=('x86_64')
  11 url="https://metacpan.org/dist/${_perl_namespace}-${_perl_module}"
  12 license=('LGPL')
  13 makedepends=('perl-extutils-depends' 'perl-extutils-pkgconfig')
  14 depends=('glib-perl' 'cairo-perl')
  15 source=("https://cpan.metacpan.org/authors/id/X/XA/XAOC/${_perl_namespace}-${_perl_module}-${pkgver}.tar.gz")
  16 sha256sums=('8d896444d71e1d0bca3d24e31e5d82bd0d9542aaed91d1fb7eab367bce675c50')
  17 options=('!emptydirs')
  18
  19 build() {
  20   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  21   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  22   export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  23   perl Makefile.PL
  24   make
  25 }
  26
  27 check() {
  28   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  29   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  30   export PERL_MM_USE_DEFAULT=1
  31   make test
  32 }
  33
  34 package() {
  35   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  36   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  37   make pure_install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
  38 }