perl-cpan-changes/trunk/PKGBUILD

   1 # Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
   2 # Contributor: John D Jones III <jnbek1972 -_AT_- g m a i l -_Dot_- com>
   3
   4 pkgname=perl-cpan-changes
   5 pkgver=0.400002
   6 pkgrel=4
   7 pkgdesc="Read and write Changes files"
   8 arch=('any')
   9 url='https://search.mcpan.org/dist/CPAN-Changes'
  10 license=('GPL' 'PerlArtistic')
  11 depends=('perl')
  12 options=('!emptydirs')
  13 source=(https://cpan.metacpan.org/authors/id/H/HA/HAARG/CPAN-Changes-$pkgver.tar.gz)
  14 sha256sums=('01eedea90d07468cb58e4a50bfa3bb1d4eeda9073596add1118fc359153abe8d')
  15
  16 build() {
  17   cd "${srcdir}"/CPAN-Changes-$pkgver
  18
  19   PERL_MM_USE_DEFAULT=1 perl Makefile.PL installdirs=vendor
  20   make
  21 }
  22
  23 check() {
  24   cd "${srcdir}"/CPAN-Changes-$pkgver
  25
  26   make test
  27 }
  28
  29 package() {
  30   cd "${srcdir}"/CPAN-Changes-$pkgver
  31
  32   make install DESTDIR="${pkgdir}"
  33
  34   find "${pkgdir}" -name '.packlist' -delete
  35   find "${pkgdir}" -name '*.pod' -delete
  36 }