perl-goocanvas2-cairotypes/trunk/PKGBUILD

   1 # Maintainer: Muflone http://www.muflone.com/contacts/english/
   2 # Contributor: PhotonX <michael dot kogan at gmx dot net>
   3
   4 pkgname=perl-goocanvas2-cairotypes
   5 _perl_module=GooCanvas2-CairoTypes
   6 pkgver=0.001
   7 pkgrel=6
   8 pkgdesc="Bridge between GooCanvas2 and Cairo types"
   9 arch=('x86_64')
  10 url="https://metacpan.org/release/${_perl_module}"
  11 license=('PerlArtistic' 'GPL')
  12 depends=('goocanvas' 'perl-gtk3')
  13 makedepends=('perl-extutils-depends' 'perl-extutils-pkgconfig')
  14 source=("https://cpan.metacpan.org/authors/id/A/AS/ASOKOLOV/${_perl_module}-${pkgver}.tar.gz")
  15 sha256sums=('ba806736ebcc9de3d8141a763a682bdeabb1cb8702bde299adfd574ace875052')
  16 options=('!emptydirs')
  17
  18 prepare() {
  19   cd "${_perl_module}-${pkgver}"
  20   sed -i "s/goocanvas-2.0/goocanvas-3.0/" Makefile.PL
  21 }
  22
  23
  24 build() {
  25   cd "${_perl_module}-${pkgver}"
  26   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  27   export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  28   perl Makefile.PL
  29   make
  30 }
  31
  32 check() {
  33   cd "${_perl_module}-${pkgver}"
  34   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  35   export PERL_MM_USE_DEFAULT=1
  36   make test
  37 }
  38
  39 package() {
  40   cd "${_perl_module}-${pkgver}"
  41   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  42   make pure_install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
  43   # Delete unuseful files
  44   find "${pkgdir}" -name '.packlist' -delete
  45 }