perl-par/trunk/PKGBUILD

   1 # Maintainer: Frederik Schwan <freswa at archlinux dot org>
   2 # Contributor: dracorp aka Piotr Rogoza <piotr.r.public at gmail.com>
   3 # Contributor:  TDY <tdy@gmx.com>
   4 # Contributor: François Charette <firmicus ατ gmx δοτ net>
   5
   6 pkgname=perl-par
   7 pkgver=1.018
   8 pkgrel=1
   9 pkgdesc='Perl Archive Toolkit'
  10 arch=('any')
  11 url='https://metacpan.org/release/PAR'
  12 license=('GPL')
  13 depends=('perl-archive-zip' 'perl-par-dist')
  14 options=('!emptydirs' purge)
  15 source=("https://cpan.metacpan.org/authors/id/R/RS/RSCHUPP/PAR-${pkgver}.tar.gz")
  16 b2sums=('e43be438dda3b3fcac1fc2b127d5081662567b492f367133c765d967803af1db2a2bbe258492109f2e5a41e864acd4a87ed551ceae3ebc5a529f1c07d7aa2fbc')
  17
  18 build() {
  19   cd PAR-${pkgver}
  20   unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
  21   export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  22   perl Makefile.PL
  23   make
  24 }
  25 check(){
  26   cd PAR-${pkgver}
  27   unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
  28   export PERL_MM_USE_DEFAULT=1
  29   make test
  30 }
  31 package() {
  32   cd PAR-${pkgver}
  33   unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
  34   make install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
  35 }