perl-pdf-api2/repos/community-any/PKGBUILD

   1 # Maintainer: Muflone http://www.muflone.com/contacts/english/
   2 # Contributor: Chad Harp <chad dot harp at mac dot com>
   3 # Contributor: FadeMind <fademind at gmail dot com>
   4 # Contributor: TDY <tdy at archlinux dot info>
   5 # Contributor: Sven Salzwedel <sven_salzwedel at web dot de>
   6 # Contributor: Olaf Leidinger <leidola at newcon dot de>
   7
   8 pkgname=perl-pdf-api2
   9 _perl_namespace=PDF
  10 _perl_module=API2
  11 pkgver=2.044
  12 pkgrel=1
  13 pkgdesc="Faciliates the creation and modification of PDF files"
  14 arch=('any')
  15 url="https://metacpan.org/release/${_perl_namespace}-${_perl_module}"
  16 license=('LGPL')
  17 depends=('perl' 'perl-font-ttf')
  18 checkdepends=('perl-test-exception' 'perl-test-memory-cycle')
  19 source=("https://www.cpan.org/modules/by-module/${_perl_namespace}/${_perl_namespace}-${_perl_module}-${pkgver}.tar.gz")
  20 sha256sums=('b2d15579e42723d8d7f9b72de86d0d35cde34f1eb7713456ba2ad35fb3cbea7e')
  21 options=('!emptydirs')
  22
  23 build() {
  24   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  25   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  26   export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  27   perl Makefile.PL
  28   make
  29 }
  30
  31 check() {
  32   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  33   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  34   export PERL_MM_USE_DEFAULT=1
  35   make test
  36 }
  37
  38 package() {
  39   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  40   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  41   make pure_install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
  42   # Delete unuseful files
  43   find "${pkgdir}" -name '.packlist' -delete
  44 }