perl-term-extendedcolor/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Steven Allen <steven@stebalien.com>
   3 # Contributor: Magnus Woldrich <magnus@trapd00r.se>
   4
   5 pkgname=perl-term-extendedcolor
   6 _cpanname=Term-ExtendedColor
   7 pkgver=0.504
   8 pkgrel=4
   9 pkgdesc='Like Term::ANSIColor, but for the extended colorset'
  10 url='https://search.cpan.org/dist/Term-ExtendedColor'
  11 arch=('any')
  12 license=('PerlArtistic' 'GPL')
  13 depends=('perl>=5.10.0')
  14 options=('!emptydirs')
  15 source=(https://search.cpan.org/CPAN/authors/id/W/WO/WOLDRICH/${_cpanname}-${pkgver}.tar.gz)
  16 sha512sums=('666c718daca2ae7191d7e92954b6ab7bc7d72add8f88a79f46554b74529c240ed36b796cdbd28aa862c6bc4394a15b5401d053dde814c12d48cc5dd295d78e42')
  17 b2sums=('9a9995f7ce0d56541fb2128c6cbf36e8b3c22613622eab61c7b6f5259f9ab36bf27471fe9d0a3b39d0f4739fb4434d7ca957442f7bba136c74c021d42ae3a660')
  18
  19 build() {
  20   cd ${_cpanname}-${pkgver}
  21   PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  22   make
  23 }
  24
  25 check() {
  26   cd ${_cpanname}-${pkgver}
  27   make test
  28 }
  29
  30 package() {
  31   cd ${_cpanname}-${pkgver}
  32   make DESTDIR="${pkgdir}" install
  33   install -Dm 644 README -t "${pkgdir}/usr/share/doc/${pkgname}"
  34   install -Dm 644 examples/* -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
  35 }
  36
  37 # vim: ts=2 sw=2 et: