plasma-maliit-framework/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Bhushan Shah <bshah@kde.org>
   3
   4 pkgname=plasma-maliit-framework
   5 pkgver=0.99.0.20150710
   6 _commit=0e273b3863d3435cfc486cf1aa9dcecfad1e180d
   7 pkgrel=4
   8 pkgdesc="Framework for Maliit integration with Plasma"
   9 arch=('x86_64')
  10 license=('GPL')
  11 url="https://cgit.kde.org/plasma-maliit-framework.git"
  12 depends=('qt5-declarative' 'kwayland' 'karchive')
  13 makedepends=('git')
  14 source=("git+https://github.com/KDE/plasma-maliit-framework.git#commit=$_commit")
  15 sha512sums=('SKIP')
  16
  17 prepare() {
  18   mkdir -p build
  19 }
  20
  21 build() {
  22   cd build
  23   qmake -makefile \
  24     CONFIG+=qt5-inputcontext \
  25     CONFIG+=nohwkeyboard \
  26     CONFIG+=enable-dbus-activation \
  27     CONFIG+=notests \
  28     CONFIG+=nodoc \
  29     ../plasma-maliit-framework
  30   make
  31 }
  32
  33 package() {
  34   cd build
  35   make install INSTALL_ROOT="$pkgdir/"
  36   mv "$pkgdir"/usr/include/maliit/framework/maliit/* "$pkgdir"/usr/include/maliit/
  37   mv "$pkgdir"/usr/include/maliit/plugins/maliit/plugins/* "$pkgdir"/usr/include/maliit/plugins/
  38   rm -r "$pkgdir"/usr/include/maliit/plugins/maliit "$pkgdir"/usr/include/maliit/framework
  39 }