primus/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
   2 # Contributor: Alexander Monakov <amonakov@gmail.com>
   3
   4 pkgname=primus
   5 pkgver=20151110
   6 pkgrel=9
   7 pkgdesc="Faster OpenGL offloading for Bumblebee"
   8 arch=('x86_64')
   9 url="https://github.com/amonakov/primus"
  10 license=('custom:ISC')
  11 depends=('bumblebee')
  12 makedepends=('git')
  13 _commit=d1afbf6fce2778c0751eddf19db9882e04f18bfd  # master
  14 source=("git+https://github.com/amonakov/primus#commit=$_commit"
  15         "register_cleanup.patch")
  16 sha1sums=('SKIP'
  17           'fd48f89c55c1ad854d7a985781faed2c52c0135f')
  18
  19 prepare() {
  20   cd primus
  21   patch -Np1 -i ../register_cleanup.patch
  22 }
  23
  24 build() {
  25   cd primus
  26   make
  27 }
  28
  29 package() {
  30   cd primus
  31
  32   sed -e '/^PRIMUS_libGL=/cPRIMUS_libGL=/usr/\\$LIB/primus' \
  33       -e '/^exec/iexport __GLVND_DISALLOW_PATCHING=1' \
  34     primusrun | install -D /dev/stdin "$pkgdir/usr/bin/primusrun"
  35
  36   install -D lib/libGL.so.1 "$pkgdir/usr/lib/primus/libGL.so.1"
  37   install -D primus.bash-completion "$pkgdir/usr/share/bash-completion/completions/primusrun"
  38   install -D primusrun.1 "$pkgdir/usr/share/man/man1/primusrun.1"
  39   install -D -m644 LICENSE.txt "$pkgdir/usr/share/licenses/primus/LICENSE"
  40 }
  41
  42 # vim:set ts=2 sw=2 et: