python-aiosignal/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _pyname=aiosignal
   4 pkgname=python-${_pyname}
   5 pkgver=1.3.1
   6 pkgrel=3
   7 pkgdesc='List of registered asynchronous callbacks'
   8 url='https://github.com/aio-libs/aiosignal'
   9 arch=('any')
  10 license=('Apache')
  11 depends=('python' 'python-frozenlist')
  12 makedepends=('python-setuptools')
  13 checkdepends=('python-pytest' 'python-pytest-cov' 'python-pytest-runner' 'python-pytest-asyncio')
  14 source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('c03454d1b855bb3e84d3ce07fb32d08855b42d1ca7723fd67d3b2ef1bc66038a31974fabda7561c90e2beaf4cdd2c28cc0463e43eb5d5c127df0cd187ae3c2e2')
  16 b2sums=('16112f674f20b97406eff16a6a9baca1ef414132ec53a67789e08347f06a462ff653c7a00d6865855f5fe0fd70ba4a2bebe286020fdf1942da41d43f72e67837')
  17
  18 build() {
  19   cd "${_pyname}-${pkgver}"
  20   python setup.py build
  21 }
  22
  23 check() {
  24   cd "${_pyname}-${pkgver}"
  25   PYTHONPATH="$PWD" \
  26   pytest -v
  27 }
  28
  29 package() {
  30   cd "${_pyname}-${pkgver}"
  31   python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
  32   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  33   install -Dm 644 CHANGES.rst README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
  34 }
  35
  36 # vim: ts=2 sw=2 et: