python-clevercsv/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 pkgname=python-clevercsv
   4 pkgver=0.7.5
   5 _commit=3bdae29f6125682639d5253d62ab782a87349513
   6 pkgrel=2
   7 pkgdesc="A Python package for handling messy CSV files"
   8 url="https://github.com/alan-turing-institute/CleverCSV"
   9 license=('MIT')
  10 arch=('x86_64')
  11 depends=('python-chardet' 'python-regex' 'python-packaging')
  12 makedepends=('git' 'python-setuptools')
  13 optdepends=('python-pandas' 'python-tabview' 'python-wilderness' 'python-cchardet')
  14 checkdepends=('python-pytest-runner' 'python-pandas' 'python-tabview' 'python-wilderness'
  15               'python-cchardet' 'python-termcolor')
  16 source=("git+https://github.com/alan-turing-institute/CleverCSV.git#commit=$_commit")
  17 sha512sums=('SKIP')
  18
  19 build() {
  20   cd CleverCSV
  21   python setup.py build
  22 }
  23
  24 check() {
  25   cd CleverCSV
  26   PYTHONPATH="$PWD"/build/lib.linux-$CARCH-3.10 python setup.py pytest
  27 }
  28
  29 package() {
  30   cd CleverCSV
  31   python setup.py install --root="$pkgdir" --optimize=1
  32   mkdir "$pkgdir"/usr/share
  33   mv "$pkgdir"/usr/man "$pkgdir"/usr/share/man
  34
  35   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  36 }