python-distlib/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Eli Schwartz <eschwartz@archlinux.org>
   3
   4 pkgname=python-distlib
   5 _pkgname="${pkgname#python-}"
   6 pkgver=0.3.6
   7 pkgrel=3
   8 pkgdesc='Low-level functions that relate to packaging and distribution of Python software'
   9 arch=('any')
  10 url='https://distlib.readthedocs.io'
  11 license=('PSF')
  12 depends=('python')
  13 makedepends=('python-setuptools' 'python-build' 'python-installer' 'python-wheel')
  14 source=("https://github.com/pypa/distlib/releases/download/$pkgver/distlib-$pkgver.tar.gz"{,.asc})
  15 b2sums=('9cd6cca18f2e2ed0c7644865644ccfa98387128ef4a4672a3fe457ee12f7625e8a01cbc8a12321262ae2e2a0c444d504bee11a2f608009d331e3a99b94206728'
  16         'SKIP')
  17 validpgpkeys=('CA749061914EAC138E66EADB9147B477339A9B86') # Vinay Sajip <vinay_sajip@yahoo.co.uk>
  18
  19 prepare() {
  20   cd "$_pkgname-$pkgver"
  21
  22   rm distlib/*.exe
  23 }
  24
  25 build() {
  26   cd "$_pkgname-$pkgver"
  27
  28   python -m build --wheel --no-isolation
  29 }
  30
  31 check() {
  32   cd "$_pkgname-$pkgver"
  33
  34   python tests/test_all.py
  35 }
  36
  37 package() {
  38   cd "$_pkgname-$pkgver"
  39
  40   python -m installer --destdir="$pkgdir" dist/*.whl
  41 }