python-et-xmlfile/repos/community-any/PKGBUILD

   1 # Maintainer: Andrzej Giniewicz <gginiu@gmail.com>
   2 # Contributor: George Rawlinson <grawlinson@archlinux.org>
   3
   4 pkgname='python-et-xmlfile'
   5 pkgver=1.1
   6 pkgrel=4
   7 pkgdesc="A low memory library for creating large XML files."
   8 arch=('any')
   9 url="https://et-xmlfile.readthedocs.io/"
  10 license=('MIT')
  11 depends=('python')
  12 makedepends=('python-setuptools')
  13 checkdepends=('python-pytest-runner' 'python-lxml')
  14 source=("https://foss.heptapod.net/openpyxl/et_xmlfile/-/archive/${pkgver}/et_xmlfile-${pkgver}.tar.gz")
  15 sha256sums=('8d6705c2f97b2d6195c95e5f3781a1ed44a59d43cf1263e04034767e5db65131')
  16
  17 prepare() {
  18   cd "$srcdir"/et_xmlfile-${pkgver}
  19   # fix deprecation warning
  20   sed -i "s/strict/strict-markers/" pytest.ini
  21 }
  22
  23 build() {
  24   cd "$srcdir"/et_xmlfile-${pkgver}
  25   python setup.py build
  26 }
  27
  28 check() {
  29   cd "$srcdir"/et_xmlfile-${pkgver}
  30   python setup.py pytest
  31 }
  32
  33 package() {
  34   cd "$srcdir"/et_xmlfile-${pkgver}
  35   python setup.py install --skip-build --root="$pkgdir" --optimize=1
  36   install -Dm644 LICENCE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENCE
  37 }