python-httplib2/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Felix Yan <felixonmars@archlinux.org>
   3 # Contributor: Alexander Rødseth <rodseth@gmail.com>
   4 # Contributor: Jan de Groot <jgc@archlinux.org>
   5 # Contributor: Giorgio Lando <patroclo7@gmail.com>
   6 # Contributor: Nicolas Quienot <niQo@aur>
   7 # Contributor: Jesse Young <jesse.young@gmail.com>
   8 # Contributor: Anton Eliasson <devel@antoneliasson.se>
   9
  10 pkgname=python-httplib2
  11 pkgver=0.22.0
  12 pkgrel=3
  13 pkgdesc='Comprehensive HTTP client library, supporting many features'
  14 arch=('any')
  15 url='https://github.com/httplib2/httplib2'
  16 license=('MIT')
  17 depends=(
  18   'ca-certificates'
  19   'python'
  20   'python-pyparsing'
  21 )
  22 makedepends=(
  23   'git'
  24   'python-build'
  25   'python-installer'
  26   'python-wheel'
  27   'python-setuptools'
  28 )
  29 checkdepends=(
  30   'flake8'
  31   'python-pytest-cov'
  32   'python-pytest-forked'
  33   'python-pytest-timeout'
  34   'python-pytest-xdist'
  35   'python-pytest-randomly'
  36   'python-future'
  37   'python-cryptography'
  38   'python-six'
  39 )
  40 _commit=09eee8a81f552cbaa74f603f2dd9bcc3311ff6d7
  41 source=(
  42   "$pkgname::git+$url#commit=$_commit"
  43   'use-system-certificates.patch'
  44 )
  45 sha512sums=('SKIP'
  46             'cb767cf95177d5a3c40dce49db0759b75a4ef3b9182ee931370386d7f380586818d8d940119907fe7a6b85504377571eb52176dcacbb37197cc85a5ae48fc149')
  47
  48
  49 pkgver() {
  50   cd "$pkgname"
  51
  52   git describe --tags | sed 's/^v//'
  53 }
  54
  55 prepare() {
  56   cd "$pkgname"
  57
  58   patch -p1 -i "$srcdir/use-system-certificates.patch"
  59
  60   sed -e 's/==/>=/' -i requirements-test.txt
  61 }
  62
  63 build() {
  64   cd "$pkgname"
  65
  66   python -m build --wheel --no-isolation
  67 }
  68
  69 check() {
  70   cd "$pkgname"
  71   # test_client_cert_password_verified fails with cryptography 36 https://github.com/httplib2/httplib2/issues/221
  72   PYTHONPATH=build/lib pytest -k 'not test_client_cert_password_verified'
  73 }
  74
  75 package() {
  76   cd "$pkgname"
  77
  78   python setup.py install --root="$pkgdir" --optimize=1
  79
  80   # license
  81   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  82 }
  83
  84 # vim:set ts=2 sw=2 et: