python-jaraco.collections/repos/community-any/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Chih-Hsuan Yen <yan12125@archlinux.org>
   3 # Contributor: Kyle Keen <keenerd@gmail.com>
   4
   5 pkgname=python-jaraco.collections
   6 pkgver=3.5.2
   7 pkgrel=3
   8 pkgdesc="Models and classes to supplement the stdlib 'collections' module."
   9 arch=('any')
  10 url='https://github.com/jaraco/jaraco.collections'
  11 license=('MIT')
  12 depends=('python-jaraco.text' 'python-jaraco.classes')
  13 makedepends=('python-build' 'python-installer' 'python-setuptools-scm' 'python-wheel')
  14 checkdepends=('python-pytest-enabler' 'python-pytest-mypy')
  15 conflicts=('python-jaraco')
  16 replaces=('python-jaraco')
  17 source=("https://files.pythonhosted.org/packages/source/j/jaraco.collections/jaraco.collections-$pkgver.tar.gz")
  18 sha512sums=('9567ee44fbc5010cc81ee24de792e53b5a225759b5f7d2e7dd932b0cae38e2035fddb5bd3dee5dc08fea9c61e2bf9087418cd192d81c72760f1e0d95a7b3788c')
  19
  20 prepare() {
  21   cd jaraco.collections-$pkgver
  22   # https://github.com/jaraco/jaraco.collections/issues/10
  23   echo "explicit_package_bases = True" >> mypy.ini
  24 }
  25
  26 build() {
  27   cd jaraco.collections-$pkgver
  28   python -m build --wheel --no-isolation
  29 }
  30
  31 check() {
  32   cd jaraco.collections-$pkgver
  33   python -m pytest
  34 }
  35
  36 package() {
  37   cd jaraco.collections-$pkgver
  38   python -m installer --destdir="$pkgdir" dist/*.whl
  39   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  40 }
  41
  42 # vim:set ts=2 sw=2 et: