python-jupyter-client/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Kyle Keen <keenerd@gmail.com>
   3
   4 _pyname=jupyter_client
   5 pkgname=python-${_pyname/_/-}
   6 pkgver=8.2.0
   7 pkgrel=2
   8 pkgdesc='Jupyter protocol implementation and client libraries'
   9 arch=(any)
  10 url='https://pypi.python.org/pypi/jupyter_client'
  11 license=(BSD)
  12 depends=(python-ipykernel python-traitlets python-pyzmq python-jupyter-core python-dateutil python-entrypoints)
  13 makedepends=(python-build python-installer python-hatchling)
  14 checkdepends=(python-pytest-jupyter python-pytest-timeout iproute2 net-tools openssh)
  15 conflicts=(python-jupyter_client)
  16 provides=(python-jupyter_client)
  17 replaces=(python-jupyter_client)
  18 source=(https://files.pythonhosted.org/packages/source/j/jupyter_client/jupyter_client-$pkgver.tar.gz)
  19 sha256sums=('9fe233834edd0e6c0aa5f05ca2ab4bdea1842bfd2d8a932878212fc5301ddaf0')
  20
  21 build() {
  22   cd $_pyname-$pkgver
  23   python -m build --wheel --no-isolation
  24 }
  25
  26 check() {
  27   cd $_pyname-$pkgver
  28   pytest -v
  29 }
  30
  31 package() {
  32   cd $_pyname-$pkgver
  33   python -m installer --destdir="$pkgdir" dist/*.whl
  34   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  35 }