python-kubernetes/trunk/PKGBUILD

   1 # Maintainer: Thore Bödecker <foxxx0@archlinux.org>
   2 # Contributor: Ian Beringer <ian@ianberinger.com>
   3
   4 pkgname=python-kubernetes
   5 _pkgbase="${pkgname#python-}"
   6 pkgver=26.1.0
   7 pkgrel=2
   8 license=('Apache')
   9 pkgdesc='Python client for the kubernetes API'
  10 arch=('any')
  11 url='https://github.com/kubernetes-client/python'
  12 depends=('python' 'python-certifi' 'python-six' 'python-dateutil'
  13          'python-urllib3' 'python-yaml' 'python-google-auth'
  14          'python-websocket-client' 'python-requests' 'python-requests-oauthlib'
  15          'python-adal')
  16 makedepends=('python-setuptools')
  17 checkdepends=('python-pytest' 'python-pluggy' 'python-py' 'python-isort' 'python-nose')
  18 source=("${_pkgbase}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
  19 sha256sums=('73bc8e450efb90ac680d8042d3498c873b6aec384db598cd829d8988db14d6f1')
  20
  21 prepare() {
  22   cd "${srcdir}"
  23
  24   mv -v "python-${pkgver}" "${_pkgbase}-${pkgver}"
  25 }
  26
  27 build() {
  28   cd "${srcdir}/${_pkgbase}-${pkgver}"
  29   python setup.py build
  30 }
  31
  32 check() {
  33   cd "${srcdir}/${_pkgbase}-${pkgver}"
  34   export PYTHONPATH="${PWD}"
  35   py.test -vvv -s --ignore=kubernetes/e2e_test
  36 }
  37
  38 package() {
  39   cd "${srcdir}/${_pkgbase}-${pkgver}"
  40   python setup.py install --root="${pkgdir}" --optimize=1
  41   install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  42 }