python-openid/repos/community-any/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2
   3 _name=python3-openid
   4 pkgname=python-openid
   5 pkgver=3.2.0
   6 pkgrel=6
   7 pkgdesc="Python 3 port of the python2-openid library"
   8 arch=('any')
   9 url="https://github.com/necaris/python3-openid"
  10 license=('Apache')
  11 depends=('python-defusedxml')
  12 makedepends=('python-setuptools')
  13 checkdepends=('python-coverage' 'python-django' 'python-httplib2'
  14 'python-mysqlclient' 'python-psycopg2' 'python-pycurl' 'python-pytest')
  15 source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
  16 sha512sums=('54412820fef21928e1bf30d16c9bc73d454e9ff41df028a12047c08abdb4c2c9e1d9053daebab8b0327cb0fe0f67e364c2506a47509fef6db5bff42f8399b799')
  17
  18 prepare() {
  19   mv -v "${_name}-${pkgver}" "$pkgname-$pkgver"
  20 }
  21
  22 build() {
  23   cd "$pkgname-$pkgver"
  24   python setup.py build
  25 }
  26
  27 check() {
  28   cd "$pkgname-$pkgver"
  29   export PYTHONPATH="build:${PYTHONPATH}"
  30   coverage run -m unittest openid.test.test_suite
  31 }
  32
  33 package() {
  34   cd "$pkgname-$pkgver"
  35   python setup.py install --skip-build \
  36     --optimize=1 \
  37     --prefix=/usr \
  38     --root="${pkgdir}"
  39   install -vDm 644 NEWS.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  40 }