python-openstacksdk/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
   3
   4 pkgname=python-openstacksdk
   5 pkgver=1.0.1
   6 _commit=3876f3f6d9d45f22de7429e14744e66439d90fdf
   7 pkgrel=2
   8 pkgdesc="An SDK for building applications to work with OpenStack"
   9 arch=('any')
  10 url="https://developer.openstack.org/sdks/python/openstacksdk"
  11 license=('Apache')
  12 depends=('python-six' 'python-pbr' 'python-yaml' 'python-jsonpatch' 'python-appdirs'
  13          'python-keystoneauth1' 'python-os-service-types' 'python-deprecation'
  14          'python-requestsexceptions' 'python-decorator' 'python-jmespath' 'python-iso8601'
  15          'python-netifaces' 'python-dogpile.cache' 'python-cryptography')
  16 makedepends=('git' 'python-setuptools')
  17 checkdepends=('python-stestr' 'python-ddt' 'python-requests-mock' 'python-oslotest'
  18               'python-jsonschema' 'python-oslo-config' 'python-prometheus_client' 'python-hacking')
  19 source=("git+https://github.com/openstack/openstacksdk.git#commit=$_commit")
  20 sha512sums=('SKIP')
  21
  22 build() {
  23   cd openstacksdk
  24   python setup.py build
  25 }
  26
  27 check() {
  28   # From https://github.com/openstack/openstacksdk/blob/master/tox.ini
  29   export OS_LOG_CAPTURE=true OS_STDOUT_CAPTURE=true OS_STDERR_CAPTURE=true
  30
  31   cd openstacksdk
  32   # TODO
  33   stestr run || echo "Tests failed"
  34 }
  35
  36 package() {
  37   cd openstacksdk
  38   python setup.py install --root="$pkgdir" --optimize=1
  39 }
  40
  41 # vim:set ts=2 sw=2 et: