python-pgpy/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: James Morris <jmorris@securityinnovation.com>
   3
   4 pkgname=python-pgpy
   5 pkgver=0.6.0
   6 pkgrel=2
   7 pkgdesc='Pretty Good Privacy for Python'
   8 arch=('any')
   9 license=('BSD')
  10 url='https://github.com/SecurityInnovation/PGPy'
  11 depends=(
  12   'python'
  13   'python-cryptography'
  14   'python-pyasn1'
  15 )
  16 makedepends=(
  17   'git'
  18   'python-setuptools'
  19 )
  20 checkdepends=(
  21   'python-pytest'
  22   'python-pytest-order'
  23 )
  24 _commit='a0e56ff79df37652208002dba9f37e29f451c8ac'
  25 source=("$pkgname::git+$url.git#commit=$_commit")
  26 b2sums=('SKIP')
  27
  28 pkgver() {
  29   cd "$pkgname"
  30
  31   git describe --tags | sed 's/^v//'
  32 }
  33
  34 build() {
  35   cd "$pkgname"
  36
  37   python setup.py build
  38 }
  39
  40 check() {
  41   cd "$pkgname"
  42
  43   pytest
  44 }
  45
  46 package() {
  47   cd "$pkgname"
  48
  49   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  50
  51   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  52 }