python-pgspecial/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: fzerorubigd <fzero@rubi.gd>
   3
   4 pkgname=python-pgspecial
   5 pkgver=2.1.0
   6 pkgrel=2
   7 pkgdesc='Meta-commands handler for PostgreSQL'
   8 arch=('any')
   9 url='https://github.com/dbcli/pgspecial'
  10 license=('BSD')
  11 depends=(
  12   'python'
  13   'python-click'
  14   'python-sqlparse'
  15   'python-psycopg'
  16 )
  17 makedepends=('git' 'python-setuptools')
  18 checkdepends=('python-pytest' 'python-configobj')
  19 _commit='d071787d9ed8da3424e43213e6695476923aebdc'
  20 source=("$pkgname::git+$url.git#commit=$_commit")
  21 b2sums=('SKIP')
  22
  23 pkgver() {
  24   cd "$pkgname"
  25
  26   git describe --tags | sed 's/^v//'
  27 }
  28
  29 build() {
  30   cd "$pkgname"
  31
  32   python setup.py build
  33 }
  34
  35 check() {
  36   cd "$pkgname"
  37
  38   PYTHONPATH="$(pwd):$PYTHONPATH" pytest --ignore tests/test_specials.py
  39 }
  40
  41 package() {
  42   cd "$pkgname"
  43
  44   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  45
  46   # documentation
  47   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.rst
  48
  49   # license
  50   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" License.txt
  51 }