python-ptrace/trunk/PKGBUILD

   1 # Maintainer: Muflone http://www.muflone.com/contacts/english/
   2 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   3 # Contributor: Sebastien Binet <binet@lblbox>
   4
   5 pkgname=python-ptrace
   6 pkgver=0.9.8
   7 pkgrel=4
   8 pkgdesc='Python binding of ptrace library to trace processes and syscalls'
   9 url='https://github.com/haypo/python-ptrace'
  10 arch=('any')
  11 license=('GPL2')
  12 depends=('python' 'python-six')
  13 makedepends=('python-sphinx' 'python-setuptools')
  14 source=(https://github.com/haypo/python-ptrace/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('f50ba7d457bf20a161a99913a552f2e829e97975d7cfbf8cf5d89b4f2320772b537678f2e70b9aaa88341c4f01d4bf41f62683e913628db503152f3510a013a3')
  16 b2sums=('3d387beca9c92c0e3bbd5cf2c9d2af447c233b631e894ce1af2cdc697a1a48e24a299bbc998cd187ac9ad0f45bfc886f476afdb69329d761e8730a047731126b')
  17
  18 build() {
  19   cd ${pkgbase}-${pkgver}
  20   python setup.py build
  21   make -j1 -C doc man text SPHINXBUILD=sphinx-build
  22 }
  23
  24 check() {
  25   cd ${pkgbase}-${pkgver}
  26   python runtests.py || echo "Warning: tests only run in an env with ptrace allowed"
  27 }
  28
  29 package() {
  30   cd ${pkgbase}-${pkgver}
  31   python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
  32   install -Dm 644 doc/build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
  33   cp -a examples "${pkgdir}/usr/share/doc/${pkgname}"
  34   install -Dm 644 doc/build/man/${pkgbase}.1 -t "${pkgdir}/usr/share/man/man1"
  35 }
  36
  37 # vim: ts=2 sw=2 et: