python-pyaxmlparser/repos/community-any/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _pyname=pyaxmlparser
   4 pkgname=python-${_pyname}
   5 pkgver=0.3.28
   6 pkgrel=1
   7 pkgdesc='Parser for Android XML file and get Application Name without using Androguard'
   8 url='https://github.com/appknox/pyaxmlparser'
   9 arch=('any')
  10 license=('Apache')
  11 depends=('python' 'python-lxml' 'python-click' 'python-asn1crypto' 'python-magic')
  12 makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools')
  13 checkdepends=('python-pytest')
  14 source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  15 sha512sums=('ede5d9821ceb71b121731462830252eade8114b9f3fb3cd1d767072f0b0a5d50764ad8d97dbacaf1cbfacd323b7aae52968bd63217beaa6290a4be442682c397')
  16 b2sums=('8b04b2e635d87501f909d592c696613b66fb33ca4fbaaa6b6b914aed7eacb5233085eb45a76f7fda440e802c972ec86682036eea53f6d87989b1bf44b0336c33')
  17
  18 prepare() {
  19   cd ${_pyname}-${pkgver}
  20   sed -i "s|man/man1|share/man/man1|g" -i setup.py
  21 }
  22
  23 build() {
  24   cd ${_pyname}-${pkgver}
  25   python -m build --wheel --no-isolation
  26 }
  27
  28 check() {
  29   cd ${_pyname}-${pkgver}
  30   PYTHONPATH=build/lib pytest
  31 }
  32
  33 package() {
  34   cd ${_pyname}-${pkgver}
  35   python -m installer --destdir="$pkgdir" dist/*.whl
  36   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  37   install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
  38 }
  39
  40 # vim: ts=2 sw=2 et: