python-pyocr/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2
   3 _pkgname=pyocr
   4 pkgname=python-pyocr
   5 pkgver=0.8.3
   6 pkgrel=2
   7 pkgdesc='Python wrapper for Tesseract and Cuneiform'
   8 arch=('any')
   9 url='https://gitlab.gnome.org/World/OpenPaperwork/pyocr'
  10 license=('GPL3')
  11 depends=('python-pillow' 'python-six')
  12 makedepends=('git' 'python-setuptools-scm')
  13 optdepends=('cuneiform: OCR backend'
  14             'tesseract: OCR backend')
  15 _commit=920b07154e1240efbd16e5b0bfd5fe2b57ac8334
  16 source=("git+https://gitlab.gnome.org/World/OpenPaperwork/pyocr.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $_pkgname
  21   git describe --tags | sed 's/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $_pkgname
  26   git revert -n c11aa77bea433f0a6f75d077bd7871a7fc0c54c1 # Remove version constraint
  27   sed -e '/setuptools_scm_git_archive/d' -i setup.py # Remove unused makedepends
  28 }
  29
  30 build() {
  31   cd $_pkgname
  32   python setup.py build
  33 }
  34
  35 package() {
  36   cd $_pkgname
  37   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  38 }