python-pytesseract/repos/community-any/PKGBUILD

   1 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   2 # Maintainer: Alexander Epaneshnikov <alex19ep@archlinux.org>
   3 # Contributor: Christoph Brill <egore911@gmail.com>
   4
   5 _name=pytesseract
   6 pkgname=python-pytesseract
   7 pkgver=0.3.10
   8 pkgrel=2
   9 pkgdesc='Python wrapper for Google Tesseract'
  10 arch=('any')
  11 url=https://github.com/madmaze/pytesseract
  12 license=('Apache')
  13 depends=('python-packaging' 'python-pillow' 'tesseract')
  14 makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
  15 checkdepends=('python-pytest' 'tesseract-data-eng' 'tesseract-data-fra')
  16 source=("$url/archive/v$pkgver/$_name-v$pkgver.tar.gz")
  17 b2sums=('d89f9082d8c7236b97bb96441809a19f494aacd23d4c02d5b7fb1b742616e7b26c249d49fceecc4f652792cdc3d7f2a79cd580a3360157f81205ff04d65afb10')
  18
  19 build() {
  20   cd $_name-$pkgver
  21   python -m build --wheel --skip-dependency-check --no-isolation
  22 }
  23
  24 check() {
  25   cd $_name-$pkgver
  26   python -m venv --system-site-packages test-env
  27   test-env/bin/python -m installer dist/*.whl
  28   test-env/bin/python -m pytest
  29 }
  30
  31 package() {
  32   cd $_name-$pkgver
  33   python -m installer --destdir="$pkgdir" dist/*.whl
  34 }
  35
  36 # vim:set ts=2 sw=2 et: