python-pyxbe/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Letu Ren <fantasquex at gmail dot com>
   3
   4 _pyname=pyxbe
   5 pkgname=python-${_pyname}
   6 pkgver=1.0.1
   7 pkgrel=3
   8 pkgdesc='Library to work with XBE files, the executable file format for the original Xbox game console'
   9 url='https://github.com/mborgerson/pyxbe'
  10 arch=('any')
  11 license=('custom:MIT')
  12 depends=('python')
  13 makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools')
  14 checkdepends=('python-pytest')
  15 source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  16 sha512sums=('07e4d8b7bc921d971cc1f7b095a33752548d94631cf8f28e586423da8182885eeef04fbebf5ef577bb774c2b6d39fcabb6c18f1ae1154f2a453af3726a36c672')
  17 b2sums=('83c4197a496422695fd300e8901378fcbee6fca4d1f5408f9e391968efb8d6d124a33a061224382a83f35f2780b1c92d37ed913b5d99e62b478d745f9c9b497b')
  18
  19 build() {
  20   cd ${_pyname}-${pkgver}
  21   python -m build --wheel --no-isolation
  22 }
  23
  24 check() {
  25   cd ${_pyname}-${pkgver}/tests
  26   PYTHONPATH="${PWD}/../build/lib" pytest
  27 }
  28
  29 package() {
  30   cd ${_pyname}-${pkgver}
  31   python -m installer --destdir="$pkgdir" dist/*.whl
  32   install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  33   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  34 }
  35
  36 # vim: ts=2 sw=2 et: