python-qstylizer/trunk/PKGBUILD

   1 # Maintainer: Bruno Pagani <archange@archlinux.org>
   2
   3 _pkg=qstylizer
   4 pkgname=python-${_pkg}
   5 pkgver=0.2.2
   6 pkgrel=2
   7 pkgdesc="Qt stylesheet generation utility for PyQt/PySide"
   8 arch=(any)
   9 url="https://github.com/blambright/qstylizer"
  10 license=(MIT)
  11 depends=(python-inflection python-tinycss2)
  12 makedepends=(python-pbr python-setuptools)
  13 checkdepends=(
  14     python-pytest
  15     python-pytest-runner
  16     python-pytest-mock
  17 )
  18 #source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
  19 source=(${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  20 sha256sums=('95f7666929cc34efbbd9e0640a13f507b8ec35ec34a9604017cf96c24f7f9ea6')
  21
  22 build() {
  23   cd ${_pkg}-${pkgver}
  24   export PBR_VERSION=${pkgver}
  25   python setup.py build
  26 }
  27
  28 check() {
  29   cd ${_pkg}-${pkgver}
  30   PYTHONPATH="${PWD}"/build/lib/ pytest
  31 }
  32
  33 package() {
  34   cd ${_pkg}-${pkgver}
  35   export PBR_VERSION=${pkgver}
  36   python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
  37   install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
  38 }