python-qt-material/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=python-qt-material
   4 pkgver=2.14
   5 pkgrel=1
   6 pkgdesc='Material inspired stylesheet for PySide & PyQt'
   7 arch=('any')
   8 url='https://qt-material.readthedocs.io/'
   9 license=('BSD' 'Apache')
  10 depends=('python-jinja')
  11 makedepends=(
  12   'git'
  13   'python-build'
  14   'python-installer'
  15   'python-wheel'
  16   'python-setuptools'
  17 )
  18 _commit='5a99be3d6914cd5570282b29968aa39a7f8d1408'
  19 source=("$pkgname::git+https://github.com/UN-GCPDS/qt-material#commit=$_commit")
  20 b2sums=('SKIP')
  21
  22 pkgver() {
  23   cd "$pkgname"
  24
  25   # first known commit to receive latest version
  26   local _pkgver='2.14'
  27   local _pkgcommit='5a99be3d6914cd5570282b29968aa39a7f8d1408'
  28
  29   git tag "$_pkgver" "$_pkgcommit"
  30
  31   #git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
  32   git describe --tags | sed 's/^v//'
  33 }
  34
  35 build() {
  36   cd "$pkgname"
  37
  38   python -m build --wheel --no-isolation
  39 }
  40
  41 package() {
  42   cd "$pkgname"
  43
  44   python -m installer --destdir="$pkgdir" dist/*.whl
  45
  46   # license
  47   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  48 }