python-socketpool/repos/community-any/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 pkgname=python-socketpool
   4 pkgver=0.5.3
   5 pkgrel=9
   6 pkgdesc="A simple Python socket pool"
   7 arch=('any')
   8 license=('MIT')
   9 url="https://github.com/benoitc/socketpool"
  10 depends=('python')
  11 makedepends=('python-setuptools' 'git')
  12 checkdepends=('python-pytest')
  13 source=("git+https://github.com/benoitc/socketpool.git#tag=$pkgver")
  14 sha512sums=('SKIP')
  15
  16 prepare() {
  17   cd "$srcdir/socketpool"
  18   sed -i 's/data_files.*$/)/' setup.py
  19   sed -i 's/isAlive/is_alive/' socketpool/backend_thread.py
  20 }
  21
  22 build() {
  23   cd "$srcdir/socketpool"
  24   LC_CTYPE=en_US.UTF-8 python setup.py build
  25 }
  26
  27 check() {
  28   cd "$srcdir/socketpool"
  29   PYTHONPATH="$PWD/build/lib:$PYTHONPATH" \
  30   py.test tests/
  31 }
  32
  33 package() {
  34   cd socketpool
  35   LC_CTYPE=en_US.UTF-8 python setup.py install --root="${pkgdir}" --optimize=1
  36   install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  37 }