python-sortedcontainers/repos/community-any/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 pkgname=python-sortedcontainers
   4 pkgver=2.4.0
   5 pkgrel=4
   6 pkgdesc="Python Sorted Container Types: SortedList, SortedDict, and SortedSet"
   7 arch=('any')
   8 license=('Apache')
   9 url="http://www.grantjenks.com/docs/sortedcontainers/"
  10 depends=('python')
  11 makedepends=('python-setuptools')
  12 checkdepends=('python-pytest-runner')
  13 source=("$pkgname-$pkgver.tar.gz::https://github.com/grantjenks/python-sortedcontainers/archive/v$pkgver.tar.gz")
  14 sha512sums=('f80185c6f95a85cc78f88f6f6cf389eb48be22cf94d5fcd84f3592873f17de37ec7f44c1627b7f02956ac4b4f74ca4febefc47d3c6232f70ee05dbb2449ad770')
  15
  16 prepare() {
  17   # Don't use tox
  18   sed -i '/tests_require/d' python-sortedcontainers-$pkgver/setup.py
  19 }
  20
  21 build() {
  22   cd python-sortedcontainers-$pkgver
  23   python setup.py build
  24 }
  25
  26 check() {
  27   cd python-sortedcontainers-$pkgver
  28   python setup.py pytest
  29 }
  30
  31 package() {
  32   cd python-sortedcontainers-$pkgver
  33   python setup.py install --root="$pkgdir" --optimize=1
  34 }