python-sphinx-alabaster-theme/trunk/PKGBUILD

   1 # Maintainer: Johannes Löthberg <johannes@kyriasis.com>
   2 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   3 # Contributor: xantares
   4
   5 _name=alabaster
   6 pkgname=python-sphinx-alabaster-theme
   7 pkgver=0.7.13
   8 pkgrel=4
   9
  10 pkgdesc="Sphinx default theme"
  11 url='https://github.com/sphinx-doc/alabaster'
  12 arch=('any')
  13 license=('custom:BSD')
  14
  15 depends=('python')
  16 makedepends=('python-build' 'python-installer' 'python-setuptools'
  17              'python-wheel')
  18
  19 source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
  20
  21 sha256sums=('a27a4a084d5e690e16e01e03ad2b2e552c61a65469419b907243193de1a84ae2')
  22 b2sums=('b67ab19b3cb4d86bc0f2bc94cbac7de42b6ffc089844d49daa5db40de942dd87555f9ed8ac362ea01904a9e77f8fe995250bd878b39c9a4851041cec8ef6460e')
  23
  24 build() {
  25   cd $_name-$pkgver
  26   python -m build --wheel --skip-dependency-check --no-isolation
  27 }
  28
  29 package() {
  30   cd $_name-$pkgver
  31   python -m installer --destdir="$pkgdir" dist/*.whl
  32
  33   # Symlink license file
  34   local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  35   install -d "$pkgdir"/usr/share/licenses/$pkgname
  36   ln -s "$site_packages"/$_name-$pkgver.dist-info/LICENSE \
  37     "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  38 }