python-spur/trunk/PKGBUILD

   1 # Maintainer: Bruno Pagani <archange@archlinux.org>
   2
   3 _pkg=spur
   4 pkgname=python-${_pkg}
   5 pkgver=0.3.23
   6 pkgrel=2
   7 pkgdesc="Run commands and manipulate files locally or over SSH using the same interface"
   8 arch=(any)
   9 url="https://github.com/mwilliamson/spur.py"
  10 license=(BSD)
  11 makedepends=(python-setuptools)
  12 depends=(python python-paramiko)
  13 checkdepends=(python-nose)
  14 # No tests in pypi tarballs
  15 #source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
  16 source=(${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  17 sha256sums=('613fcc44f731a041841485a52780c94490e59c353952c2c8491ec045a2e5d805')
  18
  19 build() {
  20   cd ${_pkg}.py-${pkgver}
  21   python setup.py build
  22 }
  23
  24 check() {
  25   cd ${_pkg}.py-${pkgver}
  26   # https://github.com/mwilliamson/spur.py/issues/85
  27   nosetests || echo "Tests failed"
  28 }
  29
  30 package() {
  31   cd ${_pkg}.py-${pkgver}
  32   python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
  33   # Install license file
  34   install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/
  35 }