python-structlog/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
   3
   4 pkgname=python-structlog
   5 # https://www.structlog.org/en/stable/changelog.html
   6 pkgver=23.1.0
   7 # curl https://api.github.com/repos/hynek/structlog/git/ref/tags/$pkgver | jq -r .object.sha
   8 _tag=785135e3db8d40c470acca88a263bb47be0c3a5d
   9 pkgrel=2
  10 pkgdesc="Structured Logging for Python"
  11 url="https://www.structlog.org"
  12 license=('Apache')
  13 arch=('any')
  14 depends=('python')
  15 makedepends=('git' 'python-build' 'python-installer'
  16              'python-hatchling' 'python-hatch-vcs' 'python-hatch-fancy-pypi-readme')
  17 checkdepends=('python-pytest' 'python-freezegun' 'python-pretend' 'python-simplejson'
  18               'python-twisted' 'python-rapidjson' 'python-greenlet' 'python-pytest-asyncio'
  19               'python-rich')
  20 optdepends=(
  21   'python-greenlet: for greenlet support in structlog.threadlocal (deprecated)'
  22   'python-twisted: for structlog.twisted'
  23   'python-rich: for structlog.dev'
  24 )
  25 # The PyPI tarball is signed, but missing conftest.py
  26 source=("git+https://github.com/hynek/structlog.git?signed#tag=$_tag")
  27 sha512sums=('SKIP')
  28 validpgpkeys=(
  29   'C2A04F86ACE28ADCF817DBB7AE2536227F69F181'  # https://keys.openpgp.org/vks/v1/by-fingerprint/C2A04F86ACE28ADCF817DBB7AE2536227F69F181
  30 )
  31
  32 pkgver() {
  33   cd structlog
  34   git describe --tags
  35 }
  36
  37 build() {
  38   cd structlog
  39   python -m build --wheel --no-isolation
  40 }
  41
  42 check() {
  43   cd structlog
  44   # Install to a temporary root for test_packaging
  45   pyver=$(python -c "import sys; print('{}.{}'.format(*sys.version_info[:2]))")
  46   python -m installer --destdir="$PWD/tmp_install" dist/*.whl
  47   PYTHONPATH="$PWD/tmp_install/usr/lib/python$pyver/site-packages" pytest tests
  48 }
  49
  50 package() {
  51   cd structlog
  52   python -m installer --destdir="$pkgdir" dist/*.whl
  53 }