qcustomplot/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2
   3 _name=QCustomPlot
   4 pkgbase=qcustomplot
   5 pkgname=('qcustomplot' 'qcustomplot-doc')
   6 pkgver=2.1.1
   7 pkgrel=1
   8 pkgdesc="Qt C++ widget for plotting and data visualization"
   9 arch=('x86_64')
  10 url="https://www.qcustomplot.com/"
  11 license=('GPL3')
  12 makedepends=('doxygen' 'graphviz' 'qt5-tools')
  13 source=(
  14   "${pkgname}-${pkgver}.tar.bz2::https://gitlab.com/DerManu/${_name}/-/archive/v${pkgver}/${_name}-v${pkgver}.tar.bz2"
  15   "${pkgname}-${pkgver}-source.tar.gz::https://www.qcustomplot.com/release/${pkgver}/${_name}-source.tar.gz"
  16 )
  17 sha512sums=('a9c0fe0c2393858b5de66e78606ef96e57b00e405e0417df7d59d5e93a89f706a1d4767316bf015c76514aedd69553229fd347569b9d68e387103486ee29988f'
  18             '1feb4f45ef90d7709edb26c9964f0ec85ef4aa30f0a7e9fcd803fae586875e8d6744dbcfe08b21f461816ca426c8a6612f8e9c7ef9d3f5a7150c3de8fa5ee57d')
  19 b2sums=('6525e5ca60ba978c2c09e86786339bd92ff4a995a170f3bc30e17e183134acb9d8d7515259eb65cb006f2cd713f1ed6bce69248fe228e8bd8a913857b0800170'
  20         '985ce5fbfe2888ac2346a8c694e832f8d9e3d20ae1c2f93af8757f6a7c803e24ae429c11240aeaf9e79625d8eb0e8a835dca023b73eac4ca1338d21434bd3c67')
  21
  22 prepare() {
  23   mv -v "${_name}-v${pkgver}" "${pkgbase}-${pkgver}"
  24   cd "${pkgbase}-${pkgver}"
  25   # move required amalgameted sources into place
  26   mv -v "../${pkgname}-source/"*.{cpp,h} .
  27 }
  28
  29 build() {
  30   cd "${pkgbase}-${pkgver}"
  31   qmake-qt5 sharedlib/sharedlib-compilation/sharedlib-compilation.pro
  32   make
  33   # create documentation
  34   doxygen
  35   qhelpgenerator documentation/html/index.qhp \
  36     -o documentation/qthelp/qcustomplot.qch
  37   find documentation/html -type f \
  38     -iname "*.qhp" -or -iname "*.map" -or -iname "*.md5" -delete
  39 }
  40
  41 package_qcustomplot() {
  42   depends=('qt5-base')
  43   provides=('libqcustomplot.so')
  44   replaces=('qcustomplot-qt5')
  45
  46   cd "${pkgbase}-${pkgver}"
  47   # there is no install target
  48   install -vDm 644 "${pkgname}.h" -t "${pkgdir}/usr/include/"
  49   install -vdm 755 "${pkgdir}/usr/lib/"
  50   cp -av "lib${pkgname}.so"* "${pkgdir}/usr/lib/"
  51   install -vDm 644 changelog.txt -t "${pkgdir}/usr/share/doc/${pkgname}/"
  52 }
  53
  54 package_qcustomplot-doc() {
  55   pkgdesc+=" (docs)"
  56
  57   cd "${pkgbase}-${pkgver}"
  58   install -vDm 644 documentation/qthelp/*.qch -t "${pkgdir}/usr/share/doc/qt/"
  59   find examples -type f -exec install -vDm 644 {} "${pkgdir}/usr/share/doc/${pkgbase}/"{} \;
  60   (
  61     cd documentation
  62     find html -type f -exec install -vDm 644 {} "${pkgdir}/usr/share/doc/${pkgbase}/"{} \;
  63   )
  64 }