qtractor/repos/community-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Ray Rashif <schiv@archlinux.org>
   3 # Contributor: speps <speps at aur dot archlinux dot org>
   4 # Contributor: Philipp Überbacher <hollunder at gmx dot at>
   5
   6 pkgname=qtractor
   7 pkgver=0.9.33
   8 pkgrel=1
   9 pkgdesc="Audio/MIDI multitrack sequencer"
  10 arch=(x86_64)
  11 url="https://qtractor.sourceforge.io/"
  12 license=(GPL2)
  13 groups=(pro-audio)
  14 depends=(
  15   gcc-libs
  16   glibc
  17   hicolor-icon-theme
  18   libmad
  19   libxcb
  20   qt6-base
  21   qt6-svg
  22   zlib
  23 )
  24 makedepends=(
  25   alsa-lib
  26   aubio
  27   clap
  28   cmake
  29   dssi
  30   jack
  31   ladspa
  32   liblo
  33   libogg
  34   libsamplerate
  35   libsndfile
  36   libvorbis
  37   lilv
  38   lv2
  39   qt6-tools
  40   rubberband
  41   suil
  42   vst3sdk
  43 )
  44 optdepends=(
  45   'new-session-manager: for session management'
  46   'qt6-wayland: for native wayland support'
  47 )
  48 provides=(
  49   clap-host
  50   dssi-host
  51   ladspa-host
  52   lv2-host
  53   vst-host
  54   vst3-host
  55 )
  56 source=(https://github.com/rncbc/$pkgname/archive/refs/tags/${pkgname}_${pkgver//./_}.tar.gz)
  57 sha512sums=('6314ae10020168f43b73c542e86bcb1ea5b088072930bfa4f2e8b89013e05a28af5de88ec7f41441d69b3bb3fbfb22868ed08a609089a48b630f3d482904d7b0')
  58 b2sums=('0e7b8345557babd8accb74f3b97f5bcb4f089bf606703b048713870f9f9757276829bbd0287ec2d1353ed52d47271c99e3ce5e59aa70a84282114cc708441627')
  59
  60 build() {
  61   local cmake_options=(
  62     -B build
  63     -DCMAKE_BUILD_TYPE=None
  64     -DCMAKE_INSTALL_PREFIX=/usr
  65     -DCONFIG_QT6=ON
  66     -S $pkgname-${pkgname}_${pkgver//./_}
  67     -Wno-dev
  68   )
  69
  70   cmake "${cmake_options[@]}"
  71   cmake --build build --verbose
  72 }
  73
  74 package() {
  75   depends+=(
  76     alsa-lib libasound.so
  77     aubio libaubio.so
  78     jack libjack.so
  79     liblo liblo.so
  80     libogg libogg.so
  81     libsamplerate libsamplerate.so
  82     libsndfile libsndfile.so
  83     libvorbis libvorbisenc.so libvorbisfile.so libvorbis.so
  84     lilv liblilv-0.so
  85     rubberband librubberband.so
  86   )
  87
  88   DESTDIR="$pkgdir" cmake --install build
  89   install -vDm 644 $pkgname-${pkgname}_${pkgver//./_}/{README,README.VST} -t "$pkgdir/usr/share/doc/$pkgname/"
  90 }