qxlsx/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Carlos Aznarán <caznaranl@uni.pe>
   3
   4 pkgbase=qxlsx
   5 pkgname=($pkgbase-qt5 $pkgbase-qt6)
   6 pkgver=1.4.6
   7 pkgrel=1
   8 pkgdesc='Excel file reader/writer library using Qt'
   9 arch=(x86_64)
  10 url='https://github.com/QtExcel/QXlsx'
  11 license=(MIT)
  12 makedepends=(cmake qt5-base qt6-base)
  13 source=(https://github.com/QtExcel/QXlsx/archive/v$pkgver/$pkgbase-$pkgver.tar.gz)
  14 sha256sums=('969a947af6a78dad9f2418dfc84e528d212ceb98e6392edf859dbff4f8828a77')
  15
  16 build() {
  17   cmake -B build5 -S QXlsx-$pkgver/QXlsx \
  18     -DCMAKE_INSTALL_PREFIX=/usr \
  19     -DQT_VERSION_MAJOR=5 \
  20     -DBUILD_SHARED_LIBS=ON
  21   cmake --build build5
  22
  23   cmake -B build6 -S QXlsx-$pkgver/QXlsx \
  24     -DCMAKE_INSTALL_PREFIX=/usr \
  25     -DQT_VERSION_MAJOR=6 \
  26     -DBUILD_SHARED_LIBS=ON
  27   cmake --build build6
  28 }
  29
  30 package_qxlsx-qt5() {
  31   depends=(qt5-base)
  32
  33   DESTDIR="$pkgdir" cmake --install build5
  34   install -Dm644 QXlsx-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  35 }
  36
  37 package_qxlsx-qt6() {
  38   depends=(qt6-base)
  39
  40   DESTDIR="$pkgdir" cmake --install build6
  41   install -Dm644 QXlsx-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  42 }