radare2-r2pipe/repos/community-any/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 pkgbase=radare2-r2pipe
   4 pkgname=(python-r2pipe)
   5 pkgver=5.7.2
   6 pkgrel=2
   7 pkgdesc='Access radare2 via pipe from any programming language'
   8 url='https://github.com/radareorg/radare2-r2pipe'
   9 arch=('any')
  10 license=('MIT')
  11 makedepends=(
  12   radare2
  13   python
  14   python-build
  15   python-installer
  16   python-setuptools
  17   python-wheel
  18   python-sphinx
  19 )
  20 source=(${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  21 sha512sums=('66abc418b8cdc8b64494a78b5227caa8ef7428f64752653313fa878736a5d98bf14a6d3b48a77b19b8cac7dd8babb5cf6955c6644b95bb49e2dbd10326711520')
  22 b2sums=('c31c11ad1504ea583a4778df1a2b3a960e8ad758cc41b1620459015e5dbf71a6ad6d87c7ef0a0fd300a9cdff39ea24c08680a2c299aba04268ba7ecc93b88f03')
  23
  24 build() {
  25   cd radare2-r2pipe-${pkgver}/python
  26   python -m build --wheel --no-isolation
  27 }
  28
  29 package_python-r2pipe() {
  30   depends=('python' 'radare2')
  31   cd radare2-r2pipe-${pkgver}/python
  32   python -m installer --destdir="$pkgdir" dist/*.whl
  33   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  34   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  35 }
  36
  37 # vim: ts=2 sw=2 et: