redo-python/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: buckket <felix@buckket.org>
   3
   4 pkgname=redo-python
   5 pkgver=0.42.d
   6 pkgrel=3
   7 pkgdesc='An implementation of the redo build system in Python'
   8 arch=('any')
   9 url='https://github.com/apenwarr/redo'
  10 license=('GPL')
  11 depends=('python')
  12 makedepends=(
  13   'git'
  14   'python-beautifulsoup4'
  15   'python-markdown'
  16 )
  17 optdepends=('python-setproctitle: pretty output')
  18 provides=('redo')
  19 conflicts=('redo-sh' 'redo-c' 'redo-jdebp')
  20 _commit='7f00abc36be15f398fa3ecf9f4e5283509c34a00' # redo-0.42d
  21 source=("$pkgname::git+$url.git#commit=$_commit")
  22 b2sums=('SKIP')
  23
  24 pkgver() {
  25   cd "$pkgname"
  26
  27   git describe --tags | sed -e 's/^redo-//' -e  's/\([[:alpha:]]\)$/.\1/'
  28 }
  29
  30 check() {
  31   cd "$pkgname"
  32
  33   # tests fail with make 4.4+
  34   rm -rf t/203-make
  35
  36   # tests fail if C/CXX/LD FLAGS are set
  37   # there's probably a cleaner way around this
  38   local L_CFLAGS L_CXXFLAGS L_LDFLAGS
  39   L_CFLAGS=$CFLAGS
  40   L_CXXFLAGS=$CXXFLAGS
  41   L_LDFLAGS=$LDFLAGS
  42
  43   unset CFLAGS CXXFLAGS LDFLAGS
  44
  45   ./do test
  46
  47   CFLAGS=$L_CFLAGS
  48   CXXFLAGS=$L_CXXFLAGS
  49   LDFLAGS=$L_LDFLAGS
  50 }
  51
  52 package() {
  53   cd "$pkgname"
  54
  55   DESTDIR="$pkgdir" ./do install
  56 }