reuse/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <george@rawlinson.net.nz>
   2 # Contributor: Max Mehl <aur at mehl dot mx>
   3 # SPDX-FileCopyrightText: 2019 Max Mehl
   4 # SPDX-License-Identifier: CC0-1.0
   5
   6 pkgname=reuse
   7 pkgver=1.1.2
   8 pkgrel=2
   9 pkgdesc='Helper tool for providing and confirming copyright and licensing information'
  10 arch=('any')
  11 url='https://reuse.software/'
  12 license=('GPL3' 'Apache' 'custom:CC0-1.0')
  13 depends=(
  14   'python'
  15   'python-debian'
  16   'python-license-expression'
  17   'python-boolean.py'
  18   'python-jinja'
  19   'python-binaryornot'
  20   'python-setuptools'
  21 )
  22 makedepends=(
  23   'git'
  24   'python-build'
  25   'python-installer'
  26   'python-wheel'
  27   'python-poetry-core'
  28 )
  29 checkdepends=('python-pytest')
  30 optdepends=(
  31   'git: git repository support'
  32   'mercurial: mercurial repository support'
  33 )
  34 _commit='86f057b616d7f8c0a9d524c1c1a25e8ee3883101'
  35 source=("$pkgname::git+https://github.com/fsfe/reuse-tool#commit=$_commit")
  36 b2sums=('SKIP')
  37
  38 pkgver() {
  39   cd "$pkgname"
  40
  41   git describe --tags | sed 's/^v//'
  42 }
  43
  44 build() {
  45   cd "$pkgname"
  46
  47   python -m build --wheel --no-isolation
  48 }
  49
  50 check() {
  51   cd "$pkgname"
  52
  53   pytest -v
  54 }
  55
  56 package() {
  57   cd "$pkgname"
  58
  59   python -m installer --destdir="$pkgdir" dist/*.whl
  60
  61   # documentation
  62   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.{rst,md}
  63
  64   # licenses
  65   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSES/*
  66
  67   sed -n '/## License/,$ p' README.md > "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  68 }