ruby-crack/trunk/PKGBUILD

   1 # Maintainer: Tim Meusel <tim@bastelfreak.de>
   2 # Contributor: Christian Rebischke <chris.rebischke@archlinux.org>
   3 # Contributor: Simon Kohlmeyer <simon.kohlmeyer@gmail.com>
   4
   5 _gemname='crack'
   6 pkgname="ruby-${_gemname}"
   7 pkgver=0.4.4
   8 pkgrel=3
   9 pkgdesc='Really simple JSON and XML parsing, ripped from Merb and Rails.'
  10 arch=('any')
  11 url='https://github.com/jnunemaker/crack/'
  12 license=('MIT')
  13 makedepends=('ruby-rdoc')
  14 depends=('ruby' 'ruby-safe_yaml' 'ruby-rexml')
  15 checkdepends=('ruby-minitest')
  16 options=(!emptydirs)
  17 source=("${url}/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz")
  18 sha512sums=('3f86c76718a3c2a65ee11b15434035396c2355a8562bdb642432a659b52c3e811e930318e0dc2df3ff06bd53ac14d0694471e425420ae3b7971f5d4f818bba87')
  19
  20 prepare() {
  21   cd "${srcdir}/${_gemname}-${pkgver}"
  22
  23   # we build with a tar ball, so `git` won't work
  24   sed --in-place 's|git ls-files|find|' "${_gemname}.gemspec"
  25
  26   # `rake` isn't an actual dependency, so we can remove it
  27   sed --in-place '/rake/d' Gemfile
  28 }
  29
  30 build() {
  31   cd "${srcdir}/${_gemname}-${pkgver}"
  32   gem build "${_gemname}.gemspec"
  33 }
  34
  35 check() {
  36   cd "${srcdir}/${_gemname}-${pkgver}"
  37   # the project doesn't use rake tasks for test
  38   # this is based on:
  39   # https://github.com/jnunemaker/crack/blob/4ecf9cf5f721dea61b8fa86280180142ead35312/script/test#L23
  40   ruby -I lib -I test -r rubygems -e 'Dir["test/**/*_test.rb"].each { |f| load f }'
  41 }
  42 package() {
  43   cd "${srcdir}/${_gemname}-${pkgver}"
  44   local _gemdir="$(gem env gemdir)"
  45   gem install --verbose --ignore-dependencies --no-user-install --install-dir "${pkgdir}/${_gemdir}" --bindir "${pkgdir}/usr/bin" "${_gemname}-${pkgver}.gem"
  46
  47   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  48   install -Dm 644 README.md History -t "${pkgdir}/usr/share/doc/${pkgname}"
  49   rm -rf "${pkgdir}/${_gemdir}/cache"
  50 }
  51
  52 # vim: ts=2 sw=2 et: