ruby-eventmachine/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Co-Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
   3 # Contributor: Carsten Feuls <archlinux@carstenfeuls.de>
   4
   5 _gemname=eventmachine
   6 pkgname=ruby-${_gemname}
   7 pkgver=1.2.7
   8 pkgrel=6
   9 pkgdesc='EventMachine: fast, simple event-processing library'
  10 url='http://rubyeventmachine.com'
  11 arch=('x86_64')
  12 license=('Ruby' 'GPL2')
  13 depends=('ruby' 'ruby-rdoc' 'openssl')
  14 options=('!emptydirs')
  15 source=(${pkgname}-${pkgver}.tar.gz::https://github.com/eventmachine/eventmachine/archive/v${pkgver}.tar.gz)
  16 sha256sums=('32692ae79bed595445d889ab83d862200a18964c395e48cfab01ba6e9ff6437c')
  17 sha512sums=('768ec084903dce4c737cf564fce7886a3e7e5b7d4a89c2baea3e998130c53dc00488eaa2d8e9b0133d9e4d8fffbde80c3025403881486a7968c2d84425cc1f50')
  18
  19 prepare() {
  20   cd ${_gemname}-${pkgver}
  21   sed 's|git ls-files README.md CHANGELOG.md GNU LICENSE|find|' -i ${_gemname}.gemspec
  22   sed 's|git ls-files|find|' -i ${_gemname}.gemspec
  23 }
  24
  25 build() {
  26   cd ${_gemname}-${pkgver}
  27   gem build ${_gemname}.gemspec
  28 }
  29
  30 package() {
  31   cd ${_gemname}-${pkgver}
  32   local _gemdir="$(ruby -e'puts Gem.default_dir')"
  33   gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}*.gem
  34   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  35   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  36   rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem" \
  37       "${pkgdir}/${_gemdir}/gems/${_gemname}-${pkgver}/ext/fastfilereader/Makefile" \
  38       "${pkgdir}/${_gemdir}/gems/${_gemname}-${pkgver}/ext/Makefile"
  39   rm -rf "${pkgdir}/${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"
  40   find "${pkgdir}/${_gemdir}" \( -name 'mkmf.log' -or -name 'gem_make.out' \) -delete
  41 }