ruby-hoe/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Bernhard Landauer <oberon@manjaro.org>
   3 # Contributor: Alexsandr Pavlov <kidoz at mail dot ru>
   4
   5 _gemname=hoe
   6 pkgname=ruby-${_gemname}
   7 _gitcommit=d748e0d6a3f6235a8b23a39632ccaf8b35023ba5
   8 pkgver=4.0.2
   9 pkgrel=1
  10 pkgdesc='Hoe is a rake/rubygems helper for project Rakefiles'
  11 url='https://www.zenspider.com/projects/hoe.html'
  12 arch=('any')
  13 license=('MIT')
  14 depends=('ruby')
  15 makedepends=('git' 'ruby-rdoc' 'ruby-rake')
  16 checkdepends=('ruby-minitest')
  17 options=('!emptydirs')
  18 source=("git+https://github.com/seattlerb/hoe#commit=${_gitcommit}")
  19 sha512sums=('SKIP')
  20
  21 pkgver() {
  22   cd ${_gemname}
  23   grep 'VERSION = "' lib/hoe.rb|sed -E 's|.*"(.+)"|\1|'
  24 }
  25
  26 build() {
  27   cd ${_gemname}
  28   rake gem
  29 }
  30
  31 check() {
  32   cd ${_gemname}
  33   rake test
  34 }
  35
  36 package() {
  37   cd ${_gemname}
  38   local _gemdir="$(gem env gemdir)"
  39   gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" \
  40     -n "${pkgdir}/usr/bin" pkg/${_gemname}-${pkgver}.gem
  41   install -Dm 644 README.rdoc -t "${pkgdir}/usr/share/doc/${pkgname}"
  42   install -Dm 644 README.rdoc -t "${pkgdir}/usr/share/licenses/${pkgname}"
  43   rm -rf cache gems/${_gemname}-${pkgver}/{ext,lib/*/*.so} \
  44     extensions/*/*/${_gemname}-${pkgver}/{mkmf.log,gem_make.out}
  45 }
  46
  47 # vim: ts=2 sw=2 et: