ruby-minitest-global_expectations/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _gemname=minitest-global_expectations
   4 pkgname=ruby-${_gemname}
   5 pkgver=1.0.1
   6 pkgrel=3
   7 pkgdesc='Support minitest expectation methods for all objects'
   8 url='https://github.com/jeremyevans/minitest-global_expectations'
   9 arch=('any')
  10 license=('MIT')
  11 depends=('ruby' 'ruby-minitest')
  12 makedepends=('ruby-rdoc' 'ruby-rake' 'ruby-bundler')
  13 options=('!emptydirs')
  14 source=(${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('0ff4b0a1015a1b7b8cbf792da8874ee0a9af83c0e1d8771fc38fabe56f9d742203dd4330cab08111d8d9ecc6ee592f0dc059b11b240b85133256e8abec8c316f')
  16 b2sums=('c08b1f899c41cf606488fa9484241c97231b89be94ffd9f10cab1d8cbe4aa234bc4a6cfed39ef3ddccca4b481df73c08d04cd8d72fdd20d9a05bd7f1eda8c1f5')
  17
  18 build() {
  19   cd ${_gemname}-${pkgver}
  20   sed -r 's|~>|>=|g' -i ${_gemname}.gemspec Rakefile
  21   rake package
  22 }
  23
  24 check() {
  25   cd ${_gemname}-${pkgver}
  26   rake test
  27 }
  28
  29 package() {
  30   cd ${_gemname}-${pkgver}
  31   local _gemdir="$(gem env gemdir)"
  32   gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" \
  33     -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
  34
  35   install -Dm 644 README.rdoc CHANGELOG -t "${pkgdir}/usr/share/doc/${pkgname}"
  36   install -Dm 644 MIT-LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  37
  38   rm -r "${pkgdir}/${_gemdir}/"{cache,gems/${_gemname}-${pkgver}/test}
  39 }
  40
  41 # vim: ts=2 sw=2 et: