ruby-pry/repos/community-any/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 pkgname=ruby-pry
   4 pkgver=0.14.2
   5 _commit=24f6190e42f24979886cf6d974b70bd7638fda46
   6 pkgrel=2
   7 pkgdesc='A runtime developer console and IRB alternative with powerful introspection capabilities'
   8 arch=(any)
   9 url='http://pry.github.io/'
  10 license=(MIT)
  11 depends=(ruby-coderay ruby-method_source)
  12 makedepends=(git)
  13 checkdepends=(ruby-rake ruby-rspec ruby-yard)
  14 options=(!emptydirs)
  15 source=(git+https://github.com/pry/pry.git#commit=$_commit)
  16 sha256sums=('SKIP')
  17
  18 prepare() {
  19   cd pry
  20   sed -i -r -e 's|~>|>=|' pry.gemspec
  21 }
  22
  23 build() {
  24   local _gemdir="$(gem env gemdir)"
  25   cd pry
  26   gem build pry.gemspec
  27   gem install \
  28     --local \
  29     --verbose \
  30     --ignore-dependencies \
  31     --no-user-install \
  32     --install-dir "tmp_install/$_gemdir" \
  33     --bindir "tmp_install/usr/bin" \
  34     pry-$pkgver.gem
  35   find "tmp_install/$_gemdir/gems/" \
  36     -type f \
  37     \( \
  38         -iname "*.o" -o \
  39         -iname "*.c" -o \
  40         -iname "*.so" -o \
  41         -iname "*.time" -o \
  42         -iname "gem.build_complete" -o \
  43         -iname "Makefile" \
  44     \) \
  45     -delete
  46   rm -r tmp_install/$_gemdir/cache
  47 }
  48
  49 check() {
  50   local _gemdir="$(gem env gemdir)"
  51   cd pry
  52   EDITOR=vim TERM=screen-256color GEM_HOME="tmp_install/$_gemdir" rake
  53 }
  54
  55 package() {
  56   cd pry
  57   cp -a tmp_install/* "$pkgdir"/
  58   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  59 }