ruby-psych/trunk/PKGBUILD

   1 # Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
   2
   3 _gemname='psych'
   4 pkgname="ruby-${_gemname}"
   5 pkgver=4.0.6
   6 pkgrel=1
   7 pkgdesc="A YAML parser and emitter"
   8 arch=('x86_64')
   9 url="https://github.com/ruby/${_gemname}"
  10 license=('MIT')
  11 depends=('ruby' 'ruby-stringio')
  12 makedepends=('ruby-bundler' 'ruby-rake' 'ruby-rake-compiler')
  13 checkdepends=('ruby-test-unit')
  14 source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  15 sha512sums=('b8eb525505f59d39b00a542a532b88f5d976683e7c17d123ca91410249943c47ecea536197f2ad85789dee4ae98ad26d888d1c3c32b0b4716b56c8c15270784d')
  16
  17 prepare() {
  18   cd "${_gemname}-${pkgver}"
  19
  20   # update gemspec/Gemfile to allow newer version of the dependencies
  21   sed --in-place --regexp-extended 's|~>|>=|g' "${_gemname}.gemspec"
  22 }
  23
  24 build() {
  25   cd "${_gemname}-${pkgver}"
  26
  27   rake compile
  28   rake build
  29 }
  30
  31 check() {
  32   cd "${_gemname}-${pkgver}"
  33
  34   rake test
  35 }
  36
  37 package() {
  38   cd "${_gemname}-${pkgver}"
  39
  40   local _gemdir="$(gem env gemdir)"
  41   local _platform="$(gem env platform | cut -d':' -f2)"
  42   local _extension_api_version="$(ruby -e 'puts Gem.extension_api_version')"
  43
  44   gem install \
  45     --local \
  46     --verbose \
  47     --ignore-dependencies \
  48     --no-user-install \
  49     --install-dir "${pkgdir}/${_gemdir}" \
  50     --bindir "${pkgdir}/usr/bin" \
  51     "pkg/${_gemname}-${pkgver}.gem"
  52
  53   install --verbose --directory --mode=0755 \
  54     "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_platform}" \
  55     "${pkgdir}${_gemdir}/specifications/default"
  56
  57   mv --verbose "${pkgdir}${_gemdir}/specifications/${_gemname}-${pkgver}.gemspec" "${pkgdir}${_gemdir}/specifications/default/${_gemname}-${pkgver}.gemspec"
  58   mv --verbose "${pkgdir}${_gemdir}/gems/${_gemname}-${pkgver}/lib/${_gemname}.rb" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_gemname}.rb"
  59   mv --verbose "${pkgdir}${_gemdir}/gems/${_gemname}-${pkgver}/lib/${_gemname}" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_gemname}"
  60   mv --verbose "${pkgdir}${_gemdir}/extensions/${_platform}/${_extension_api_version}/${_gemname}-${pkgver}/${_gemname}.so" "${pkgdir}/usr/lib/ruby/${_extension_api_version}/${_platform}/${_gemname}.so"
  61
  62   # remove unrepreducible files
  63   rm --force --recursive --verbose \
  64     "${pkgdir}${_gemdir}/cache/" \
  65     "${pkgdir}${_gemdir}/build_info/" \
  66     "${pkgdir}${_gemdir}/extensions/" \
  67     "${pkgdir}${_gemdir}/gems/" \
  68     "${pkgdir}${_gemdir}/plugins/" \
  69     "${pkgdir}${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"
  70
  71   install --verbose -D --mode=0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  72   install --verbose -D --mode=0644 *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
  73 }