ruby-rb-inotify/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _gemname=rb-inotify
   4 pkgname=ruby-rb-inotify
   5 pkgver=0.10.1
   6 pkgrel=2
   7 pkgdesc='Thorough inotify wrapper for Ruby using FFI'
   8 url='https://github.com/guard/rb-inotify'
   9 arch=('any')
  10 license=('MIT')
  11 depends=('ruby' 'ruby-ffi')
  12 makedepends=('ruby-rdoc')
  13 options=('!emptydirs')
  14 source=(${pkgname}-${pkgver}.tar.gz::https://github.com/guard/rb-inotify/archive/v${pkgver}.tar.gz)
  15 sha256sums=('0953e27e19d48be3e41a93419f2d7a2618b36c18fe398d87e5cb1abc5a3621ea')
  16 sha512sums=('fb8484b3c019ff471dbea57ad305c32a9d03377f8bbcb4d1631ef498b3207bc83da08889f7d43fe3a9ba54df2d9164e3a83d001797f8113ddc2e3a7f2ad9a83b')
  17
  18 prepare() {
  19   cd ${_gemname}-${pkgver}
  20   sed -r 's|~>|>=|g' -i ${_gemname}.gemspec # don't give a fuck about rubys bla bla
  21   sed 's|git ls-files|find -type f|' -i ${_gemname}.gemspec
  22 }
  23
  24 build() {
  25   cd ${_gemname}-${pkgver}
  26   gem build ${_gemname}.gemspec
  27 }
  28
  29 package() {
  30   cd ${_gemname}-${pkgver}
  31   local _gemdir="$(gem env gemdir)"
  32   gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
  33   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  34   install -Dm 644 README.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
  35   rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
  36 }
  37
  38 # vim: ts=2 sw=2 et: