ruby-samus/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _gemname=samus
   4 pkgname=ruby-${_gemname}
   5 pkgver=3.0.9
   6 pkgrel=2
   7 pkgdesc='Helps you automate the release of Open Source Software'
   8 url='https://github.com/lsegal/samus'
   9 arch=('any')
  10 license=('MIT')
  11 depends=('ruby')
  12 makedepends=('ruby-rake' 'ruby-rdoc')
  13 options=('!emptydirs')
  14 source=(${url}/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz)
  15 sha512sums=('da03a00ce0ced8249a696c6b558499939316a84f8aede86829557c31aaec3621adaff3e969b1fec32fc3249ba2f244b1adca545a2f7c4a9b9fdae7629194191b')
  16 b2sums=('049a9f8691d7df77ce4721d6ca306fccc26f167b0dba954a5e90a16dc7ce3baf92288583d3b601dfee8b6160c5b48541317b5a09e61a70612b6c63da7b2899fa')
  17
  18 prepare() {
  19   cd ${_gemname}-${pkgver}
  20   sed -r 's|~>|>=|g' -i ${_gemname}.gemspec
  21   sed 's|git ls-files|find|' -i ${_gemname}.gemspec
  22 }
  23
  24 build() {
  25   cd ${_gemname}-${pkgver}
  26   gem build ${_gemname}.gemspec
  27 }
  28
  29 package() {
  30   cd ${_gemname}-${pkgver}
  31   local _gemdir="$(gem env gemdir)"
  32   gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" \
  33     -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
  34   install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  35   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  36
  37   cd "${pkgdir}/${_gemdir}"
  38   rm -rf cache gems/${_gemname}-${pkgver}/{ext,lib/*/*.so,man} \
  39     extensions/*/*/${_gemname}-${pkgver}/{mkmf.log,gem_make.out}
  40 }
  41
  42 # vim: ts=2 sw=2 et: